Second Life Physics Scripting - Pinball #21 - Puck Flipper Collisions

Blackjack! No, pinball! I think we have a game! At least the mechanic of a game. This is the first time I've felt like this could actually be a little bit fun to play and I feel like I'm geting closer to something playable. Very cool.

Here is the puck flipper collision script.

   collision_start(integer total_number)
    {
        if (llDetectedName(0) == "ball")
        {
            // positions are in global coordinates

            // find the position of the collision...
            vector colpos = llDetectedPos(0);
            //llOwnerSay("colpos = "+(string)colpos);
            
            // find the location of the puck prim
            vector locpos = llGetPos();
            //llOwnerSay("locpos = "+(string)locpos);
            
            // subtract two to get local coordinates on the puck
            colpos = locpos - colpos;
            //llOwnerSay("colpos = "+(string)colpos);
            
            // divide by the global rotation so we are back
            // in the original build orientation
            rotation locrot = llGetRot();
            colpos = colpos / locrot;
            //llOwnerSay("colpos after rot = "+(string)colpos);
            
            // find the size of the wedge
            vector sz = llList2Vector(llGetPrimitiveParams([PRIM_SIZE]),0);
            //llOwnerSay("puck size = "+(string)sz);
            // this size is pre-rotations. We are interested in the Y value
            
            // find the width of the puck
            float puckwid = sz.y/4;
            
            // the start of the puck, origin is center so divide by 2
            float puckstart = (curval * puckwid) - (sz.y/2);
            float puckend = puckstart + puckwid + puck_overlap;
            puckstart = puckstart - puck_overlap;
            
            if ((colpos.y>=puckstart) && (colpos.y<=puckend))
            {
                //llOwnerSay("PUCK IN CURCOL "+(string) curval);
                
                // the dir we what to pushin 
                vector pushdir = <1,0,0>;
                pushdir = pushdir * locrot;
                //llOwnerSay("push dir = "+(string)pushdir);
                
                llPushObject(llDetectedKey(0), pushdir, <0,0,0>, FALSE);                
            }
            else
            {
                // shoot it towards the back wall because
                // if it is going slow and they get the puck
                // under the ball it seems like it should shoot away
                // the dir we what to pushin 
                vector pushdir = <-1,0,0>;
                pushdir = pushdir * locrot;
                //llOwnerSay("push dir = "+(string)pushdir);
                
                llPushObject(llDetectedKey(0), pushdir, <0,0,0>, FALSE);                
            }
        }
    }

Since the last version I added the checks to see which portion of the puck flipper the ball is actually hitting. Just a simple division by the number of pucks in the texture and then a check to see if it is in the currently active portion of the puck.

After playing with it for a while I added the extra push towards the back wall if it isn't in the puck area. It seemed like I was able to move the puck under the ball a lot and it felt like it should shoot away, but there is really no easy way to tell where the ball is every move of the puck, so I decided to shoot it towards the back wall.

Up next, a ball launcher and a ball killer when it hits the back wall. From there, a game start and game end condition, then maybe some extras besides simple bumpers. Somewhere in there I'll have to move to some real art from the plywood. Very cool.